Перейти к содержимому


Загрузка изображения на ipic.su:
Фотография

UOPilot, PW и все все все


  • Авторизуйтесь для ответа в теме
Сообщений в теме: 4

#1 Inosss

Inosss

    ("\ (о_О) /")

  • Безумцы
  • PipPipPipPipPipPipPipPipPipPip
  • 3 750 сообщений
  • Регистрация: 10.10.2008
  • Пол (sex):Не определился (undecided)
  • Город (city):Москва

Отправлено 18 Март 2021 - 16:44

Однажды, совсем уж и не так чтобы давно Симели за коим то фигом потащил меня на уютный алькоровый сервачок, и я за коим то фигом снова согласился на очередное пвшное задротство. Нотип мы уже в который там раз в пв возвращаемся? просто создать перса и вперёд.... такое. Сим сделал ферму из 6ти персов, собственно бонус патя из всех классов, ну и предложил сзять троих себе. Штош. Почму и нет?

 

На выходе мы имеем 6 окон, которые постоянно нужно туда сюда табать и это прям боль и страдание. В те моменты, когда мы одновременно онлайн - 3 окна. Сначала с непривычки кажется что это даже маловастенько, но в стопяцотый раз делать одно и то же даже на 3х окнах немного...удручает. Засим была придумана афигитительная идея. За время после классики я играл в вов, подсмотрена была она в общем то там. Мультибоксинг.

 

Если коротко - это софтина, которая транслирует всё что делается в одном окне во все остальные окна, передвигаемся одним "главным" окном, остальные привязываются к первому с помощью "следовать". Выклядит забавно, идёт, скажем, толпа варлоков, которые тебя нафиг шотают с одного скила, или там 5 петов одновременно тебя загрызают...В общем веселуха. Ну и после небольшого поигрывания на ферме в 6 окон сама собой напрашивалась мысль о реализации подобного в ПВ. А если учесть что на клауди окна уже разблочены и не фризятся в фоне - не нужно даже париться с отдельным по для размораживания оных. Итак, беремся за работу.

 

Пилот взят отсюда: https://uopilot.uoki.../index_rus.html

 

Дальше скорее всего пойдёт сумбурный набор из листингов пилотовых скриптов с кратенькими пояснениями, скидываю всё это говно "как есть", авось кому то пригодится. Кстати, чукча не программист, так что говнокод вас скорее всего будет огорчать, но что уж, тщетность бытия и всётакое, можете написать лучше - вперёд. Ну и рефакторинг эт не про меня хД

 

 

 

В качестве подготовки - на всех персах нужно сделать одинаковые панельки, одинаковые хоткеи, всякие служебные вещи аля полётов, медитации, ассиста и прочего говна на одинаковых кнопках. Поскольку сервак помер просто скрин вставить я уже не могу, поэтому по ходу статьи это будет обясняться прям в скриптах.

 

Итак, начнём с залогинивания всех персов в игру, создания в отдельном файлике массива id всех процессов ПВ(это нужно чтобы мочь обратиться к каждому конкретному окну и знать какое окно каким классом является) и взятия всех 6ти окон в пати. Заместки что куда в комментах, после "//"

// taskkill /F /IM elementclient.exe
// set windowpos -7 0 1935 1050
exec taskkill /F /IM elementclient.exe  // киляем уже открытые окна с ПВ
set #windows 6  // Два варианта: 6 окон или 3 окна

for #i 1 #windows  //цикл, запускаем то количество окон, указанное выше в переменной #windows, все скрипты адаптированны под 3 или 6 окон
    exec C:\Cloudy World\element\elementclient.exe  //путь до клиента укажите своего!!
end_for
wait 12000  //пауза для того чтобы клиенты прогрузиться успели. Зависит от шустроты компа, можно сократить попробовать

set %handler findwindow ("Cloudy World - Лучшая")  //ищем процессы ПВ по имени окна, ищется совпадение строки, так что можно только часть впихнуть названия окна.
set #mainwindow %handler[1 1] //обозначиваем "главное окно", это будет cw_mage из списка ниже. У мага в друзьях должны быть только остальные персонажи фермы.
set $pswd 1234567890 // собсн пароль для всех учеток
set %characters[1] cw_mage  // Обьявляем массив с логинами от всех учеток
set %characters[2] cw_warrior //тудаже
set %characters[3] cw_barbarian
set %characters[4] cw_werefox
set %characters[5] cw_priest
set %characters[6] Inosss //всё ещё массив с учетками, ахаха

FileDelete (Scripts/handlers.txt) //удаляем файлик с хэндлерами окон, пилот корректно не перезаписывает этот файл. Поэтому удаляем, а дальше создадим его с нуля.

for #i 1 size(%handler)  //в массиве с хендлерами перебираем все окна
    set workwindow %handler[#i 1]   //устанавливаем одно активное окно, в него будут отправляться все комманды
    set windowpos -7 0 1935 1050  //ручками подобранное разрешение, чтобы в оконном режиме пв было во всё свободное пространство монитора. Важно иметь одно разрешение у всех окон.
    write (Scripts/handlers.txt %handler[#i 1]\r\n) //Записываем хэндлер окна в файл, нужно для других скриптов.
    showwindow TOP //чтобы видеть что вообще происходит, текущее активное окно вытаскиваем наверх всех окон
    send {Enter}  //отправляем энтер, чтобы закрыть какую то всчплывающую хрень, после этого становится видно окно логина. Это только на клауди, в других проектах можно удалить. Наверное.
    wait 500
    if #windows != 3  //при 6ти окнах пишем логин перса из массива
        send %characters[#i]
    else              //при 3х окнах - пишем логин перса, но со смещением внутри массива. Типо мои были cw_werefox cw_priest и Inosss, вот и сдвигаем массив на 3 элемента, чтобы логинить только их. Если играть одному на 6ть окон - можно это всё вообще игнорить
        set #j #i
        set #j #j + 3
        send %characters[#j]
    end_if
    send {Tab} //табаемся на окно с паролем
    send $pswd //вводим пароль
    send {Enter} //ну вы поняли, а дальше куча нажатий энтера чтобы залогиниться и паузы, на раздумья сервера
    wait 3000
    send {Enter}
    wait 300
    send {Enter}
    wait 300
    send {Enter}
    wait 2000
end_for

set workwindow #mainwindow //устанавливаем активным главное окно- тобишь маг
showwindow TOP
wait 5000

if #windows = 6 //берём всю ферму в пати
set #PartyXRight 225 // X точки, посередине первой буквы первого первого перса фермы в друзьях
set #PartyYRight 265 // Y точки, посередине первой буквы первого первого перса фермы в друзьях
set #PartyXLeft 295 // X точки, посередине слова "пригласить"
set #PartyYLeft 290 // Y точки, посередине слова "пригласить"
set #PartyXAlarm 930 // X точки, в центре знака восклицания при приёме в группу
set #PartyYAlarm 165 // Y точки, в центре знака восклицания при приёме в группу
set #PartyXYes 900 // X точки, в центре кнопки "Да"
set #PartyYYes 535 // Y точки, в центре кнопки "Да"
set #SocialButtonX 1850 // X точки, в центре кнопки c Облачком
set #SocialButtonY 985  // Y точки, в центре кнопки c Облачком
set #FriendButtonX 1814  // X точки, в центре кнопки c Друзями
set #FriendButtonY 939   // Y точки, в центре кнопки c Друзями

set #PartySize size(%handler) - 1

//send217 F // Pay respects
left #SocialButtonX, #SocialButtonY workwindow
left #FriendButtonX, #FriendButtonY workwindow

for #i 1 #PartySize 
    right #PartyXRight, #PartyYRight workwindow
    left #PartyXLeft, #PartyYLeft workwindow
    set #PartyYRight #PartyYRight + 20
    set #PartyYLeft #PartyYLeft + 20
end_for

for #i 1 size(%handler)
    if %handler[#i 1] != #mainwindow
        set workwindow %handler[#i 1]
        left #PartyXAlarm, #PartyYAlarm workwindow
        left #PartyXYes, #PartyYYes workwindow
        set workwindow #mainwindow
    end_if
end_for
//send217 F // Pay respects
left #FriendButtonX, #FriendButtonY workwindow
left #SocialButtonX, #SocialButtonY workwindow
end_if
end_script

Первое что больше всего бесит в управлении кучей окон - передвижение, постоянно надо привязывать персов друг к другу, табаться чтобы это сделать, фе короче. Начал я именно с решения задачи автоследования по одной кнопке всех персов за "главным". Тыкаем обязательно из окна пати лидера, иначе кто то из пати вывалится лол. Обычно у нас патилидер был тигра, это удобно.

set linedelay 0 //чтобы быренько всё работало, по дефолту задержка между строками 100мс. Все нужные задержки мы сами пропишем в коде.
//set hotkeystart {F1} //биндим скрипт на Ф1. В игре тыкаем ф1 после первого запуска ручного скрипта и вуаля. Вообще, по хорошему, удалить эту строку и руками в пилоте биндить скрипты надо, иначе могут быть ошибки.
load_array %handlers handlers.txt //загружаем из файлика наш массив с хендлерами окон.
set #CurrentWindow getwindow (0) // текущее окно(где мы нажали ф1), запоминается как текущее
set workwindow #CurrentWindow 

for #i 1 size(%handlers) //для всех окон, кроме текущего делаем магию!
    if %handlers[#i] != #CurrentWindow
        set workwindow %handlers[#i] //делаем активным нужного перса 

        call follow //собственно вызов процедуры, в которой описано следование за персом, где мы нажали ф1
        set workwindow #CurrentWindow 
    end_if
end_for
End_script


proc follow
    left 15, 164 workwindow // Выбираем первого члена пати для отмены макросов, координаты нужно под себя править. Это любое место в окне пати, где кликом можно выбрать первого в группе
    wait 10
    left 48, 48 workwindow // Выбираем себя для отмены макросов и текущих кастов, что то да сработает из этих 2х строчек
    send {Escape}
    right 15, 164 workwindow // Выбираем первого члена пати для отмены макросов
    wait 10
    left 55, 206 workwindow //ващпе не помню что это о_О
    wait 10
end_proc

на выходе, после выполнения скрипта, а это где то пол секунды - вся пати бодро бежит за активным персом. Оч удобно, например, выбрать окно с танком, рулить им, а остальных тащить за собой. Скрипт отменяет все текущие касты персов, так что его использовать можно ещё и для этой цели.

 

 

Ещё один скрипт на перемещение - юзаем рунки и портаем всю пати в одно место:

// Fleet warp - У любого окна тыкаем рунку, открывается карта, наводим мышку на нужный пункт назначения и нажимаем хоткей скрипта, все варпают.
set linedelay 30
//set hotkeystart {Insert}
set #CurrentWindow getwindow (0)
set workwindow #CurrentWindow
set %handler findwindow ("Cloudy World - Лучшая")

get mouse_pos #WarpX #WarpY
left #WarpX, #WarpY workwindow //запоминаем позицию мыши, чтобы дальше всеми окнами ткнуть нужный пункт назначения.

for #i 1 size(%handler)
    if %handler[#i 1] != #CurrentWindow
        set workwindow %handler[#i 1]
//        showwindow TOP
//        set #a FindImage (0 0 2000 2000  (F:\work\rune.bmp) %ResultArray) // здесь был автопоиск руны на панели, но это работает оч плохо, если на локе есть туман или какое то хитрожопое освещение - оно ниробит, так что лесом.
//       left %ResultArray[1 1], %ResultArray[1 2] workwindow  //жмякаем рунку
         left 1600, 947 // координаты руны, вытащенной на панельку. Должно быть одинаково расположено у всех персов.
         left #WarpX, #WarpY workwindow
    end_if
    set workwindow #CurrentWindow
//    showwindow TOP
end_for
End_script

А вот тут залезем всей фермой на полёты, второе нажатие - слезть:

//Залезть на полёт
set linedelay 10
//set hotkeystart {F4}
load_array %handlers handlers.txt
set #mainwindow %handlers[1] // Первое загруженное окно

for #i 1 size(%handlers)
    set workwindow %handlers[#i]
    send {Space}
    wait 100
    send {Space}
    send217 G //На панельку выносим полёт, задаём хоткей в игре. Пилот пройдёт по всем окнам и нажмёт хоткей полёта
end_for
end_script

Набор высоты в фоновом режиме сделать не вышло, но хоть чото. Для неспешных игроков - вот скрипт на набор высоты, но он работает только в активном окне, тоесть мы по очереди перебираем все окна и взлетаем вверх. В целом юзабельно, но медленно:

//Набор высоты
set linedelay 10
//set hotkeystart {F6}
load_array %handlers handlers.txt
set #CurrentWindow getwindow (0)

for #i 1 size(%handlers)
    set workwindow %handlers[#i]
    showwindow TOP
    sendex_down {Space}
    wait 3000
    sendex_up {Space}
end_for
set workwindow #CurrentWindow
showwindow TOP
end_script

Тоже самое для медитации всей патей - с помощью медитации можно прервать автоследование например, набрать чи перед скриптом для аое заливки мобов и вообще посидеть на жопке:

set linedelay 0
//set hotkeystart {Home}
load_array %handlers handlers.txt
for #i 1 size(%handlers)
    set workwindow %handlers[#i]
    send217 Z //медитация у всех на Z
end_for
end_script

Ну чтож, с передвижениями разобраись - теперь самое интересное - дамаг по ассисту с активным окном. Активное окно - должно быть пати лидером. Удобно бегать на оборе, тыкаем моба в таргет и нажимаем хоткей скрипта - остальные в пати его бьют:

set linedelay 10
//set hotkeystart {F5}
load_array %handlers handlers.txt
set #CurrentWindow getwindow (0)
set workwindow #CurrentWindow

for #i 1 size(%handlers)
    if %handlers[#i] != #CurrentWindow
        set workwindow %handlers[#i]
        if size(%handlers) = 3 //для 3х окон
            if #i = 1 or #i = 3 //это номера персов в массиве хендлеров, которые будут дамагать. Ну тип, не будем же мы пристом дамагать? Прист будет хилить в соседнем макросе. номера можно сопоставить в скрипте с логином персонажей.
                call damage
            end_if
        else //для 6ти окон
            if #i = 1 or #i = 6 or #i = 4 or #i = 2  //это номера персов в массиве хендлеров, которые будут дамагать. Ну тип, не будем же мы пристом дамагать? Прист будет хилить в соседнем макросе. номера можно сопоставить в скрипте с логином персонажей.
                call damage
            end_if
        end_if
    end_if
end_for
End_script

proc damage  //ДОМАЖНАЯ ПРОЦЭДУРА!! МВАХАХА
    left 47, 50 workwindow // Выбираем себя для отмены текущих действий
    send217 {Esc} // отменяем касты
    left 15, 164 workwindow // Выбираем первого члена пати.
    send217 ё // Тыкаем ассист. Пилот неумеет в тильду, а вот Ё прокатывает о_О В хоткеях игры на панельке стоит ассист по тильде.
    wait 300 // Без задержки траблы с ассистом,если не все персы начинают дамагать, можно увеличить задержку
    send 8
end_proc

Хорошо, а что насчёт хила? Патилидер всё ещё тигра, прист его хиляет:

 set linedelay 10
//set hotkeystart {F2}
load_array %handlers handlers.txt
if size(%handlers) = 3
    set $PristHandler %handlers[2] // Порядковый номер приста в массиве %characters, скрипт login_all_character
    set workwindow $PristHandler
else
    set $PristHandler %handlers[5] // Порядковый номер приста в массиве %characters, скрипт login_all_character
    set workwindow $PristHandler
end_if
//set workwindow 67682
left 15, 164 workwindow // Выбираем первого члена пати.
send 8 //здесь у нас макрос с хилом зацикленный. на клауди это работает. Если как на классике нельзя зациклить один спелл - можно хилить макросом хотка+столб, или запихнуть сюда цикл с постоянным нажатием хотки, но тогда нужно ещё придумать как его остановить.
End_script

Ну а если кто то словил плюху или аоеху? Как хилить его? Скрипт на хил таргета патилидера, выделяем тигрой перса в ферме, тыкаем хоткей скрипта и вуаля, его хилит прист:

set linedelay 10
//set hotkeystart {F3}
load_array %handlers handlers.txt
if size(%handlers) = 3
    set $PristHandler %handlers[2]
    set workwindow $PristHandler
    left 47, 50 workwindow // Выбираем себя для отмены макроса
    send217 {Esc}
    left 15, 164 workwindow // Выбираем первого члена пати.
    wait 300 // Задержка нужна чтобы сменился таргет, иначе при смене кастовать не будет.
    send217 F //массхил на 3х окнах
else
    set $PristHandler %handlers[5] // Порядковый номер приста в массиве %characters, скрипт login_all_character
    set workwindow $PristHandler
    left 47, 50 workwindow // Выбираем себя для отмены макроса
    send217 {Esc}
    left 15, 164 workwindow // Выбираем первого члена пати.
    send217 ё // Тыкаем ассист. Пилот неумеет в тильду, а вот Ё прокатывает о_О
    wait 300 // Задержка нужна чтобы сменился таргет, иначе при смене кастовать не будет.
    // сюда для хила цели мб стоит впихнуть сначала столб, только потом макрос на реген.
    send217 Q  //столб
    wait 300
    send217 E //хотка
    wait 300
    send217 F // массхилл, выберите как и что хилить, у меня было так.
end_if
End_script

А может бафаться тоже будем скриптами?

set linedelay 0
//set hotkeystart {PageUp}
load_array %handlers handlers.txt
for #i 1 size(%handlers)
    set workwindow %handlers[#i]
    if size(%handlers) = 3
        if #i = 1 // Лиса выбирает в таргет танка для бафа шипов
            left 15, 164 workwindow // Выбираем первого члена пати.
        end_if
    else
        if #i = 4 // Лиса выбирает в таргет танка для бафа шипов
            left 15, 164 workwindow // Выбираем первого члена пати.
        end_if
    end_if
    send 7 //на семёрке скрипт для бафа у каждого класса. У лисы - просто шипы, у мага... Да пофиг на мага.
end_for
end_script

Хорошо, теперь мы умеем передвигаться всей фермой, хилить, бафаться, дамажить, летать, варпать рунками, может что то посложнее сделаем? Изи, скрипт для аое заливки мобов, например сценарий для инея:

 

1. Юзаем скрипт с медитацией, копим фулл чи

2. Нахиливаем тигру хотками скриптом на хил патилидера

3. Жмякаем следование за патилидером, два раза, на первый прист перестанет кастовать, на второй привяжется как и вся пати к танку

4. Собираем мобов в парик, как обычно делается, юзаем черепаху

5. Юзаем сий волшебный скрипт:

// скрипт для инея

set linedelay 0
load_array %handlers handlers.txt
set #CurrentWindow getwindow (0)
set workwindow #CurrentWindow

for #i 1 size(%handlers)
    if %handlers[#i] != #CurrentWindow
        set workwindow %handlers[#i]
            left 47, 50 workwindow // Выбираем себя для отмены макроса
            send217 {Esc}
            left 15, 164 workwindow // Выбираем первого члена пати.
            send217 ё // Тыкаем ассист. Пилот неумеет в тильду, а вот Ё прокатывает о_О Здесь мы обычно выбираем открывашку в инее, или боса, или самого толстого моба.
            wait 300 // Без задержки траблы с ассистом
            send 6 //на 6ке у все пати стоят макросы на аое дамаг или сфера у приста. Вар - макрос с аоехами и станами, маг - карусель, лук - макрос раскол и буря стрел, у лисы саранча и зацикленная аоеха
    end_if
end_for
End_script

Тащем то наша задача на танке - юзануть черепаху, массагр, хвост, присутствие, в общем разберётесь. Таким макаром можно по кусочкам проходить весь иней в одно рыло.

 

 

Ну и до кучи скрипт на покупку яшмы, для клауди изи, для остальных серваков нужно править, чтобы су торговца покупать а не из встроенного магазина:

// покупка яшмы. Ставим окно магазина так, чтобы верхняя граница окошка магазина было ровно под словом группа, а левая граница - как продолжение вниз буквы Г
set linedelay 20
set #CurrentWindow getwindow (0)
set %handlers findwindow ("Cloudy World - Лучшая")


for #i 1 size(%handlers)
    set workwindow %handlers[#i 1]
    showwindow TOP
    set #YashmaLvl 4
    set #ShopX 1660
    set #ShopY 57
    set #TabChangeX 302
    set #TabChangeY 201
    set #ByFirstYashmaX 146
    set #ByFirstYashmaY 328
    set #ByButtonX 232
    set #ByButtonY 524
    set #ExitButtonX 406
    set #ExitButtonY 160

    left #ShopX, #ShopY workwindow
    left #TabChangeX, #TabChangeY workwindow
    for #j 1 5
        call YashmaLvl #YashmaLvl #TabChangeX #TabChangeY #ByFirstYashmaX #ByFirstYashmaY
        set #ByFirstYashmaX #ByFirstYashmaX + 35
    end_for
    left #ByButtonX, #ByButtonY workwindow
    left #ExitButtonX, #ExitButtonY workwindow
end_for
set workwindow #CurrentWindow
showwindow TOP
End_script

proc YashmaLvl #YashmaLvl #TabChangeX #TabChangeY #ByFirstYashmaX #ByFirstYashmaY
    switch #YashmaLvl
        case 1: set #count 1
            break
        case 2: set #count 3
            break
        case 3: set #count 9
            break
        case 4: set #count 27
            break
    end_switch

    right #ByFirstYashmaX, #ByFirstYashmaY workwindow
    wait 100
    send217 {Backspace}
    //wait 100
    send #count
    //wait 100
    send {Enter}
end_proc

Крафт яшмы нужного лвл, правим уровень яшмы в скрипте:

// Крафт яшмы. Ставим окно крафта так, чтобы верхняя граница окошка магазина было ровно под словом группа, а левая граница - как продолжение вниз буквы Г
set linedelay 100
set %handlers findwindow ("Cloudy World - Лучшая")
set #CurrentWindow getwindow (0)

for #i 1 size(%handlers)
    set workwindow %handlers[#i 1]
    showwindow TOP
    set #YashmaLvl 2
    set #TabChangeX 380
    set #TabChangeY 223
    set #CraftFirstYashmaX 162
    set #CraftFirstYashmaY 278
    set #MaxButtonX 276
    set #MaxButtonY 421
    set #CreateButtonX 242
    set #CreateButtonY 643
    set #ExitButtonX 406
    set #ExitButtonY 160

    left 142, 445 workwindow //Выбираем пункт в разговоре с алхимиком
    left #TabChangeX, #TabChangeY workwindow
    for #j 1 5
        for #k 1 4
            left #CraftFirstYashmaX, #CraftFirstYashmaY workwindow
            left #MaxButtonX, #MaxButtonY workwindow
            left #CreateButtonX, #CreateButtonY workwindow
            wait 600
            set #CraftFirstYashmaY #CraftFirstYashmaY + 35
        end_for
        set #CraftFirstYashmaY #CraftFirstYashmaY - 140
        set #CraftFirstYashmaX #CraftFirstYashmaX + 35
    end_for
    set #CraftFirstYashmaX #CraftFirstYashmaX - 175
    //left #ExitButtonX, #ExitButtonY workwindow
end_for
left 425, 163  workwindow // закрываем окно крафта
set workwindow #CurrentWindow
showwindow TOP
End_script

Вот така хуйня малята. Может я немного поздновато выкладываю, но всётаки так или иначе это будет полезно. Пока играли я искренне думал что сделаю нормальный рефакторинг всего этого добра, но случилось то что случилось, и теперь уже мне лень. Пользуйтесь, на вопросы отвечу, советом помогу, но писать всё за вас под новый серв не буду. 0/


Vividarium Et Intervigilium Et Viator
ows_T-54.png

 

109021-4.png


#2 Inosss

Inosss

    ("\ (о_О) /")

  • Безумцы
  • PipPipPipPipPipPipPipPipPipPip
  • 3 750 сообщений
  • Регистрация: 10.10.2008
  • Пол (sex):Не определился (undecided)
  • Город (city):Москва

Отправлено 18 Март 2021 - 16:49

А вот так в пилоте настраиваются хоткеи для скриптов:

https://prnt.sc/10p4clc


Vividarium Et Intervigilium Et Viator
ows_T-54.png

 

109021-4.png


#3 Jakem

Jakem

    Angry

  • Безумцы
  • PipPipPipPipPipPipPipPipPipPip
  • 3 132 сообщений
  • Регистрация: 14.12.2013
  • Пол (sex):Мужчина (man)
  • Город (city):Кривой Рог, Украина
  • Game:League of Legends, Monster Hunter World, Rainbow Six Siege
  • Наставник в AO:Не выбран

Награды

              

Отправлено 22 Март 2021 - 02:11

я вот все жду когда разрабы поймут что пк геймеры хотят ммошку где можно одновременно управлять несколькими персонажами как в rts чтобы быть сам-себе-пати но при этом чтобы можно было и одним персонажем управлять, в общем как друид/мипо в доте 2


do you guys not have phones? ( ͡° ͜ʖ ͡°)


#4 Inosss

Inosss

    ("\ (о_О) /")

  • Безумцы
  • PipPipPipPipPipPipPipPipPipPip
  • 3 750 сообщений
  • Регистрация: 10.10.2008
  • Пол (sex):Не определился (undecided)
  • Город (city):Москва

Отправлено 01 Апрель 2021 - 19:31

Ну в целом способ выше ето всё позволяет. А потом меня забанили из за пилота в вов.


Vividarium Et Intervigilium Et Viator
ows_T-54.png

 

109021-4.png


#5 ПтирЯ

ПтирЯ

    Флудо-Бог

  • Безумцы
  • PipPipPipPipPipPipPipPipPipPip
  • 2 313 сообщений
  • Регистрация: 13.10.2009
  • Пол (sex):Мужчина (man)
  • Наставник в AO:Не выбран

Отправлено 01 Апрель 2021 - 20:37

В Eve это все легально есть :D






Количество пользователей, читающих эту тему: 1

0 пользователей, 1 гостей, 0 скрытых пользователей

Яндекс.Метрика
Наши кнопки

Гильдийный счет (Яндекс.Деньги) 41001343732038

Огромное спасибо компании ЗЕНОН www.zenon.ru за отличный хостинг!

Любая перепечатка материалов форума insane.su - только с разрешения администрации или самих авторов.
В онлайн-издания перепечатка разрешена при указании ссылки на оригинал.